**Program 18.4** SAS Code for Weighted Mantel-Haenszel Test with Strata

%macro WMHTestwithStrata ( J = , /\* number of strata \*/

inA= , /\* incidence rates for the strata \*/

inB= , /\* allocation probability for control group \*/

inP1=, /\* success probability for control group \*/

phi =, /\* odds ratio under H1 \*/

power=, /\* power \*/

alpha=, /\* alpha \*/

sides= /\* 1: one-sided test 2: Two-sided test \*/

);

proc iml;

%let K = 2; /\* two groups \*/

A=&inA; B =&inB;P1=&inP1;

P2 =J(&J,1,0);Q1 =J(&J,1,0); Q2 =J(&J,1,0);

do j=1 to &J;

Q1[j]=1-P1[j];

P2[j]=&phi\*P1[j]/(Q1[j]+&phi\*P1[j]);

Q2[j]=1-P2[j];

end;

z\_p1=1-&alpha/&sides; z\_alpha = probit(z\_p1);

z\_p2=&power; z\_beta = probit(z\_p2);

delta = 0; s0\_sq= 0; s1\_sq= 0;

do j=1 to &J;

delta = delta+A[j]\*B[j]\*(1-B[j])\*(P1[j]-P2[j]);

s1\_sq= s1\_sq+A[j]\*B[j]\*(1-B[j])\*((1-B[j])\*P1[j]\*Q1[j]+B[j]\*P2[j]\*Q2[j]);

s0\_sq= s0\_sq+A[j]\*B[j]\*(1-B[j])\*(B[j]\*P1[j]+(1-B[j])\*P2[j])\*(B[j]\*Q1[j]+(1-B[j])\*Q2[j]);

end;

n = (1/(delta\*\*2))\*((sqrt(s0\_sq)\*z\_alpha+sqrt(s1\_sq)\*z\_beta)\*\*2);

print 'Sample Size Calculation';

print 'Weighted Mantel-Haenszel Test with Strata';

alpha = &alpha; power = &power; phi= &phi; sides = &Sides;

print alpha power phi sides ;

print A B P1 P2;

print delta s0\_sq s1\_sq;

print n;

quit;

run;

%mend WMHTestwithStrata;

/\*---------------- Run the macro for Example 18.4. ----------------------------------\*/

%WMHTestwithStrata(

J = 5 , /\* number of strata \*/

inA= %str({0.15, 0.15, 0.2, 0.25, 0.25}), /\*Incidence Rates for Strata \*/

inB= %str({0.4 , 0.4, 0.5, 0.6, 0.6}), /\* Allocation Probability \*/

inP1=%str({0.5 , 0.6, 0.7, 0.8, 0.9}), /\* Success Probability \*/

phi = 2, /\* odds Ratio Under H1 \*/

power =0.8, /\* Power \*/

alpha = 0.05, /\* Alpha \*/

sides = 2 /\* Two-sided test \*/

);